Add dev-qt from an older version of the gentoo repo

Qt5 has been removed, we restore it since we still use it.

dev-qt/linguist/linguist-5.15.16.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} != *9999* ]]; then
+	QT5_KDEPATCHSET_REV=1
+	KEYWORDS="amd64 ~arm arm64 ~hppa ppc64 x86"
+fi
+
+QT5_MODULE="qttools"
+inherit desktop qt5-build xdg-utils
+
+DESCRIPTION="Graphical tool for translating Qt applications"
+
+IUSE=""
+
+DEPEND="
+	=dev-qt/designer-${QT5_PV}*
+	=dev-qt/qtcore-${QT5_PV}*:5=
+	=dev-qt/qtgui-${QT5_PV}*:5=[png]
+	=dev-qt/qtprintsupport-${QT5_PV}*
+	=dev-qt/qtwidgets-${QT5_PV}*
+	=dev-qt/qtxml-${QT5_PV}*
+"
+RDEPEND="${DEPEND}
+	!dev-qt/${PN}:5
+	!<dev-qt/qtchooser-66-r2
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/linguist/linguist
+)
+
+src_install() {
+	qt5-build_src_install
+	qt5_symlink_binary_to_path linguist
+
+	local size
+	for size in 16 32 48 64 128; do
+		newicon -s ${size} src/linguist/linguist/images/icons/linguist-${size}-32.png linguist.png
+	done
+	make_desktop_entry "${QT5_BINDIR}"/linguist 'Qt 5 Linguist' linguist 'Qt;Development;Translation'
+}
+
+pkg_postinst() {
+	qt5-build_pkg_postinst
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	qt5-build_pkg_postrm
+	xdg_icon_cache_update
+}