Add dev-qt from an older version of the gentoo repo

Qt5 has been removed, we restore it since we still use it.

dev-qt/qtprintsupport/qtprintsupport-5.15.18.ebuild

@@ -0,0 +1,44 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} != *9999* ]]; then
+	QT5_KDEPATCHSET_REV=1
+	KEYWORDS="amd64 arm arm64 ~hppa ~loong ppc ppc64 ~riscv x86"
+fi
+
+QT5_MODULE="qtbase"
+VIRTUALX_REQUIRED="test"
+inherit qt5-build
+
+DESCRIPTION="Printing support library for the Qt5 framework"
+
+IUSE="cups gles2-only"
+
+RDEPEND="
+	=dev-qt/qtcore-${QT5_PV}*:5=
+	=dev-qt/qtgui-${QT5_PV}*[gles2-only=]
+	=dev-qt/qtwidgets-${QT5_PV}*[gles2-only=]
+	cups? ( net-print/cups )
+"
+DEPEND="${RDEPEND}
+	test? ( =dev-qt/qtnetwork-${QT5_PV}* )
+"
+
+QT5_TARGET_SUBDIRS=(
+	src/printsupport
+	src/plugins/printsupport
+)
+
+QT5_GENTOO_CONFIG=(
+	cups
+)
+
+src_configure() {
+	local myconf=(
+		$(qt_use cups)
+		-opengl $(usex gles2-only es2 desktop)
+	)
+	qt5-build_src_configure
+}